From 5742e1f66c4e70151865de7092547223898bbf6b Mon Sep 17 00:00:00 2001
From: Julian Blake Kongslie
Date: Sun, 18 Apr 2021 16:00:54 -0700
Subject: Support a proper PDP-8 assembler.

---
 mem/fib.pal   | 117 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mem/hello.pal |  30 +++++++++++++++
 2 files changed, 147 insertions(+)
 create mode 100644 mem/fib.pal
 create mode 100644 mem/hello.pal

(limited to 'mem')

diff --git a/mem/fib.pal b/mem/fib.pal
new file mode 100644
index 0000000..6f56109
--- /dev/null
+++ b/mem/fib.pal
@@ -0,0 +1,117 @@
+	*200
+MAIN,	CLA
+	TAD (-26)
+	DCA FIBN
+	DCA FIB0
+	IAC
+	DCA FIB1
+LOOP,	CLA
+	TAD FIB0
+	JMS PUTN
+	CLA
+	TAD (054)
+	JMS PUTC
+	CLA
+	TAD FIB0
+	TAD FIB1
+	DCA FIB2
+	TAD FIB1
+	DCA FIB0
+	TAD FIB2
+	DCA FIB1
+	ISZ FIBN
+	JMP LOOP
+EXIT,   HLT
+	CLA IAC
+	DCA FIB1
+	DCA FIB0
+        JMP MAIN
+PUTN,	0
+	JMS ITOA
+	CMA IAC
+	IAC
+	CMA IAC
+	DCA 10
+PUTNL,	CLA
+	TAD I 10
+        SPA
+        JMP I PUTN
+	TAD (60)
+	JMS PUTC
+	JMP PUTNL
+PUTC,	0
+	TLS
+	TSF
+	JMP .-1
+	JMP I PUTC
+ITOA,	0
+	DCA ITOAV
+	DCA ITOAD
+	DCA ITOAD+1
+	DCA ITOAD+2
+	DCA ITOAD+3
+	TAD (-14)
+	DCA ITOAN
+ITOAL,	CLL		/ LOOP OVER BINARY INPUT BITS
+	TAD ITOAD+3
+	JMS ITOA2X
+	DCA ITOAD+3
+	TAD ITOAD+2
+	JMS ITOA2X
+	DCA ITOAD+2
+	TAD ITOAD+1
+	JMS ITOA2X
+	DCA ITOAD+1
+	TAD ITOAD
+	JMS ITOA2X
+	DCA ITOAD
+	CLL
+	TAD ITOAV	/ SHIFT MSB OUT OF INPUT VALUE
+	RAL
+	DCA ITOAV
+	RAL
+	TAD ITOAD+3	/ ADD SHIFTED-OUT MSB TO DECIMAL LSD
+	DCA ITOAD+3
+	ISZ ITOAN
+	JMP ITOAL	/ NEXT LOOP ITERATION
+	TAD (ITOAD)
+	DCA ITOAR
+ITOAJ,	TAD I ITOAR
+	SZA
+	JMP ITOAX
+	ISZ ITOAR
+	TAD I ITOAR
+	SZA
+	JMP ITOAX
+	ISZ ITOAR
+	TAD I ITOAR
+	SZA
+	JMP ITOAX
+	ISZ ITOAR
+ITOAX,	CLA
+	TAD ITOAR
+	JMP I ITOA
+ITOA2X,	0
+	RAL		/ PUTS 0 IN LINK
+	DCA ITOAT
+	TAD (-12)
+	TAD ITOAT	/ PUTS 1 IN LINK IF WRAPPED
+	SMA
+	DCA ITOAT
+	CLA
+	TAD ITOAT
+	JMP I ITOA2X
+FIB0,	0
+FIB1,	1
+FIB2,	0
+FIBN,	-27
+ITOAD,	0		/ OUTPUT DIGITS (MSD FIRST)
+	0
+	0
+	0
+	4000		/ OUTPUT SENTINEL
+ITOAN,	0		/ INPUT BITS LOOP COUNTER
+ITOAR,	0		/ POINTER TO FIRST NONZERO DIGIT
+ITOAT,	0		/ SCRATCHPAD FOR ITOA2X
+ITOAV,	0		/ VALUE BEING CONVERTED (TEMPORARY)
+$
diff --git a/mem/hello.pal b/mem/hello.pal
new file mode 100644
index 0000000..437ccf9
--- /dev/null
+++ b/mem/hello.pal
@@ -0,0 +1,30 @@
+	*200
+START,	CLA CLL
+	TAD HELLO
+	DCA 10
+LOOP,	TAD I 10
+	SNA
+	JMP EXIT
+	TLS
+	TSF
+	JMP .-1
+	CLA
+	JMP LOOP
+EXIT,	HLT
+	JMP START
+HELLO,	.
+	"H
+	"e
+	"l
+	"l
+	"o
+	",
+	" 
+	"w
+	"o
+	"r
+	"l
+	"d
+	"!
+	0
+$
-- 
cgit v1.2.3